Pool temperature sensor

Hi guys.

Here is the code for the pool temperature sensor project. You’ll find the video in the sidebar or on YouTube.

#include <Arduino.h>
#include <OneWire.h>
#include <DallasTemperature.h>
#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <PubSubClient.h>

const char* SSID = "your_ssid";
const char* PSK = "your_password";
const char* hostname = "PoolTempSensor";
const char* MQTT_BROKER = "mqtt_broker_ip";

WiFiClient espClient;
PubSubClient client(espClient);
char msg[50];
unsigned long lastMsg = 0;

#define ONE_WIRE_BUS 4
#define Anzahl_Sensoren_DS18B20 1 // Define how many sensors you want to use 
 
#define DS18B20_Aufloesung 12
DeviceAddress DS18B20_Adressen;
 
OneWire oneWire(ONE_WIRE_BUS); 
DallasTemperature myDS18B20(&oneWire); 
 
 
const float No_Val = 999.99;
float Temperatur[Anzahl_Sensoren_DS18B20];

//setup wifi and wait for connection
void setup_wifi() {
    delay(10);
    Serial.println();
    Serial.print("Connecting to ");
    Serial.println(SSID);
 
    WiFi.mode(WIFI_STA); 
    WiFi.hostname(hostname);
    WiFi.begin(SSID, PSK);
 
    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }
 
    Serial.println("");
    Serial.println("WiFi connected");
    Serial.println("IP address: ");
    Serial.println(WiFi.localIP());
}

void setup() {
  Serial.begin(9600);
  Serial.println("DS18B20 Test");
  Serial.println();

  setup_wifi();

  delay(100);
 
  Serial.print("Anzahl aktivierter Sensoren: ");
  Serial.println(Anzahl_Sensoren_DS18B20);
 
  if ((Anzahl_Sensoren_DS18B20 > 0)) {
    myDS18B20.begin();
    Serial.print("Anzahl angeschlossener Sensoren: ");
    Serial.println(myDS18B20.getDeviceCount(), DEC);
    Serial.println();
 
    for(byte i=0 ;i < myDS18B20.getDeviceCount(); i++) {
      if(myDS18B20.getAddress(DS18B20_Adressen, i)) {
        myDS18B20.setResolution(DS18B20_Adressen, DS18B20_Aufloesung);
      }
    }
  }

  client.setServer(MQTT_BROKER, 1883);
}

//reconnect wifi if disconnected
void reconnect() {
    while (!client.connected()) {
        Serial.print("Reconnecting...");
        if (!client.connect("ESP8266Client")) {
            Serial.print("failed, rc=");
            Serial.print(client.state());
            Serial.println(" retrying in 5 seconds");
            delay(5000);
        }
    }

    //client.subscribe("/basement/office/toplight");
    Serial.println("MQTT Connected...");
}

void loop() {
    if (!client.connected()) {
        reconnect();
    }
    client.loop();
  
  if ((Anzahl_Sensoren_DS18B20 > 0)) {
    myDS18B20.requestTemperatures();
 
    for(byte i=0 ;i < Anzahl_Sensoren_DS18B20; i++) {
      if (i < myDS18B20.getDeviceCount()) {
	  
        Serial.print("Sensor ");
        Serial.print(i+1);
        Serial.print(": "); 
		
		Temperatur[i] = myDS18B20.getTempCByIndex(i);
		if (Temperatur[i] == DEVICE_DISCONNECTED_C) {
	  	  Temperatur[i] = No_Val;
		  Serial.println("Fehler");
		}
        else {
          Serial.print(Temperatur[i]);
          Serial.println(" 'C");
          char msg[8]; // Buffer big enough for 7-character float
          dtostrf(Temperatur[i], 6, 2, msg);
          client.publish("your/topic", msg);
          Serial.println("");
          Serial.print(msg);
          Serial.println(" an MQTT Broker gesendet!");
        }
      }
    }
  }
  Serial.println();
  Serial.println("Going into deep sleep now...");
  delay(5000);
  ESP.deepSleep(1800*1000000);
}
Share

You may also like...

Leave a Reply

Your email address will not be published. Required fields are marked *